# Copyright (c) 2022-2024 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/test.gni")
import("../../../../common/config/common.gni")

module_output_path = "enterprise_device_management/enterprise_device_management"

config("module_private_config") {
  visibility = [ ":*" ]
  include_dirs = [ "../" ]
}

config("edm_config") {
  visibility = [ ":*" ]
  include_dirs = [
    "../../../../services/edm/include",
    "../../../../services/edm/include/connection",
    "../../../../services/edm/include/database",
    "../../../../services/edm/include/strategy",
    "../../../../services/edm_plugin/include/utils",
    "../../../../framework/extension/include",
  ]
}

ohos_static_library("edmservice_static") {
  testonly = true
  sources = [
    "../../../../services/edm/src/admin.cpp",
    "../../../../services/edm/src/admin_manager.cpp",
    "../../../../services/edm/src/admin_policies_storage_rdb.cpp",
    "../../../../services/edm/src/application_state_observer.cpp",
    "../../../../services/edm/src/connection/enterprise_admin_connection.cpp",
    "../../../../services/edm/src/connection/enterprise_admin_proxy.cpp",
    "../../../../services/edm/src/connection/enterprise_bundle_connection.cpp",
    "../../../../services/edm/src/connection/enterprise_conn_manager.cpp",
    "../../../../services/edm/src/connection/enterprise_update_connection.cpp",
    "../../../../services/edm/src/database/edm_rdb_data_manager.cpp",
    "../../../../services/edm/src/database/edm_rdb_open_callback.cpp",
    "../../../../services/edm/src/device_policies_storage_rdb.cpp",
    "../../../../services/edm/src/enterprise_device_mgr_ability.cpp",
    "../../../../services/edm/src/enterprise_device_mgr_stub.cpp",
    "../../../../services/edm/src/permission_manager.cpp",
    "../../../../services/edm/src/plugin_manager.cpp",
    "../../../../services/edm/src/policy_manager.cpp",
    "../../../../services/edm/src/strategy/enhance_execute_strategy.cpp",
    "../../../../services/edm/src/strategy/replace_execute_strategy.cpp",
    "../../../../services/edm/src/strategy/single_execute_strategy.cpp",
    "../../../../services/edm/src/user_policy_manager.cpp",
    "../../../../services/edm_plugin/src/utils/clipboard_policy_serializer.cpp",
    "../../../../services/edm_plugin/src/utils/clipboard_utils.cpp",
    "../../../../services/edm_plugin/src/utils/password_policy_serializer.cpp",
    "../../../../services/edm_plugin/src/utils/usb_policy_utils.cpp",
  ]

  public_configs = [
    ":edm_config",
    "../../../../common/config:coverage_flags",
  ]

  defines = []

  if (target_cpu == "arm64") {
    defines += [ "_ARM64_" ]
    print("defines _ARM64_")
  }

  if (target_cpu == "x86_64") {
    defines += [ "_X86_64_" ]
    print("defines _X86_64_")
  }

  if (common_event_service_edm_enable) {
    defines += [ "COMMON_EVENT_SERVICE_EDM_ENABLE" ]
  }

  external_deps = [
    "ability_base:want",
    "ability_runtime:app_manager",
    "ability_runtime:extension_manager",
    "access_token:libaccesstoken_sdk",
    "access_token:libtokenid_sdk",
    "bundle_framework:appexecfwk_base",
    "cJSON:cjson",
    "c_utils:utils",
    "common_event_service:cesfwk_innerkits",
    "hilog:libhilog",
    "init:libbegetutil",
    "ipc:ipc_core",
    "jsoncpp:jsoncpp",
    "pasteboard:pasteboard_client",
    "relational_store:native_rdb",
    "safwk:system_ability_fwk",
    "user_auth_framework:userauth_client",
  ]

  external_deps += [
    "drivers_interface_usb:libusb_proxy_1.0",
    "usb_manager:usbsrv_client",
  ]

  deps = [
    "../../../../common/external:edm_external_adapters",
    "../../../../common/native:edm_commom",
    "../../../../interfaces/inner_api:edmservice_kits",
    "../../../../interfaces/inner_api/plugin_kits:plugin_kits",
  ]

  sanitize = {
    boundary_sanitize = true
    cfi = true
    cfi_cross_dso = true
    debug = false
    integer_overflow = true
    ubsan = true
  }
  branch_protector_ret = "pac_ret"
  subsystem_name = "customization"
  part_name = "enterprise_device_management"
}

ohos_unittest("EdmServicesUnitTest") {
  module_out_path = module_output_path

  include_dirs = [
    "./include",
    "./include/mock",
    "../../common/mock/include",
    "../../external_mock/include",
    "../../../../interfaces/inner_api/plugin_kits/include/utils",
  ]

  sources = [
    "./src/admin_manager_test.cpp",
    "./src/admin_test.cpp",
    "./src/device_policies_storage_rdb_test.cpp",
    "./src/enterprise_admin_connection_test.cpp",
    "./src/enterprise_bundle_connection_test.cpp",
    "./src/enterprise_conn_manager_test.cpp",
    "./src/enterprise_device_mgr_ability_test.cpp",
    "./src/enterprise_update_connection_test.cpp",
    "./src/iplugin_template_test.cpp",
    "./src/permission_manager_test.cpp",
    "./src/plugin_manager_test.cpp",
    "./src/policy_manager_test.cpp",
    "./src/user_policy_manager_test.cpp",
  ]

  defines = []
  if (common_event_service_edm_enable) {
    defines += [ "COMMON_EVENT_SERVICE_EDM_ENABLE" ]
  }

  configs = [
    ":module_private_config",
    "../../../../common/config:coverage_flags",
  ]

  deps = [
    ":edmservice_static",
    "../../../../common/external:edm_external_adapters",
    "../../../../common/native:edm_commom",
    "../../../../interfaces/inner_api:edmservice_kits",
    "../../../../interfaces/inner_api/plugin_kits:plugin_kits",
    "../../utils:edm_unittest_utils",
    "//third_party/googletest:gmock_main",
  ]

  external_deps = [
    "ability_base:want",
    "ability_runtime:ability_manager",
    "access_token:libaccesstoken_sdk",
    "access_token:libnativetoken",
    "access_token:libtoken_setproc",
    "bundle_framework:appexecfwk_core",
    "cJSON:cjson",
    "c_utils:utils",
    "common_event_service:cesfwk_innerkits",
    "hilog:libhilog",
    "ipc:ipc_core",
    "jsoncpp:jsoncpp",
    "safwk:system_ability_fwk",
    "samgr:samgr_proxy",
    "user_auth_framework:userauth_client",
  ]

  if (os_account_edm_enable) {
    external_deps += [
      "os_account:libaccountkits",
      "os_account:os_account_innerkits",
    ]
    defines += [ "OS_ACCOUNT_EDM_ENABLE" ]
  }

  sanitize = {
    boundary_sanitize = true
    cfi = true
    cfi_cross_dso = true
    debug = false
    integer_overflow = true
    ubsan = true
    blocklist = "../../cfi_blocklist.txt"
  }
  branch_protector_ret = "pac_ret"
  subsystem_name = "customization"
  part_name = "enterprise_device_management"
}

group("unittest") {
  testonly = true

  deps = [
    # deps file
    ":EdmServicesUnitTest",
  ]
}