# Copyright (c) 2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/ability/ability_runtime/ability_runtime.gni")

config("connection_obs_manager_public_config") {
  defines = [ "AMS_LOG_TAG = \"Ability\"" ]
  defines += [ "AMS_LOG_DOMAIN = 0xD001300" ]
  visibility = [ ":*" ]
  visibility +=
      [ "${ability_runtime_test_path}/unittest/connection_observer_test/*" ]
  include_dirs = [
    "include",
    "${ability_runtime_services_path}/common/include",
  ]
  cflags = []
  if (target_cpu == "arm") {
    cflags += [ "-DBINDER_IPC_32BIT" ]
  }
}

ohos_shared_library("connection_obs_manager") {
  branch_protector_ret = "pac_ret"

  sources = [
    "src/connection_data.cpp",
    "src/connection_observer_client.cpp",
    "src/connection_observer_client_impl.cpp",
    "src/connection_observer_proxy.cpp",
    "src/connection_observer_stub.cpp",
    "src/connection_observer_stub_impl.cpp",
    "src/dlp_connection_info.cpp",
    "src/dlp_state_data.cpp",
    "src/service_proxy_adapter.cpp",
  ]

  public_configs = [ ":connection_obs_manager_public_config" ]

  deps = []

  external_deps = [
    "ability_base:want",
    "c_utils:utils",
    "hilog:libhilog",
    "ipc:ipc_core",
    "samgr:samgr_proxy",
  ]

  cflags_cc = []
  if (os_dlp_part_enabled) {
    cflags_cc += [ "-DWITH_DLP" ]
  }

  public_external_deps = [ "bundle_framework:appexecfwk_base" ]
  innerapi_tags = [ "platformsdk" ]
  subsystem_name = "ability"
  part_name = "ability_runtime"
}