# Copyright (c) 2021 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/arkui/ace_engine/ace_config.gni")

template("card_frontend") {
  forward_variables_from(invoker, "*")

  ohos_source_set(target_name) {
    subsystem_name = ace_engine_subsystem
    part_name = ace_engine_part
    defines += invoker.defines
    configs = [ "$ace_root:ace_config" ]

    sources = [
      "$ace_root/frameworks/bridge/declarative_frontend/ng/frontend_delegate_declarative_ng.cpp",
      "card_frontend.cpp",
      "card_frontend_declarative.cpp",
      "card_frontend_delegate.cpp",
      "card_frontend_delegate_declarative.cpp",
      "form_frontend_declarative.cpp",
      "form_frontend_delegate_declarative.cpp",
      "js_card_parser.cpp",
    ]

    deps = [ "$ace_root/frameworks/core/components/theme:build_theme_code" ]
    if (use_hilog) {
      external_deps = [ "hilog:libhilog" ]
    }

    if (!defined(config.build_for_preview) || !config.build_for_preview) {
      if (form_fwk_enable) {
        external_deps += [
          "form_fwk:fmskit_native",
          "form_fwk:form_manager",
        ]
      }
    }
  }
}

foreach(item, ace_platforms) {
  card_frontend("card_frontend_" + item.name) {
    defines = []
    config = {
    }

    if (defined(item.config)) {
      config = item.config
    }

    if (defined(config.defines)) {
      defines = config.defines
    }
  }
}