# Copyright (c) 2021-2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/arkui/ace_engine/ace_config.gni")

template("bridge_accessibility") {
  forward_variables_from(invoker, "*")

  ohos_source_set(target_name) {
    subsystem_name = ace_engine_subsystem
    part_name = ace_engine_part
    defines += invoker.defines
    cflags_cc += invoker.cflags_cc

    configs = [ "$ace_root:ace_config" ]
    assert(defined(platform) && platform != "", "platform must be defined")

    sources = [ "accessibility_node_manager.cpp" ]

    deps = [
      "$ace_root/frameworks/core/accessibility/js_inspector:js_inspector_$platform",
      "$ace_root/frameworks/core/components/theme:build_theme_code",
    ]
    if (use_hilog) {
      external_deps = [ "hilog:libhilog" ]
    }
  }
}

foreach(item, ace_platforms) {
  bridge_accessibility("bridge_accessibility_" + item.name) {
    platform = item.name
    defines = []
    cflags_cc = []
    config = {
    }

    if (defined(item.config)) {
      config = item.config
    }

    if (defined(config.defines)) {
      defines = config.defines
    }

    if (defined(config.cflags_cc)) {
      cflags_cc = config.cflags_cc
    }
  }
}