# Copyright (c) 2023 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/bundlemanager/app_domain_verify/app_domain_verify.gni")

config("app_domain_verify_extension_config") {
  defines = []
  if (target_cpu == "arm64") {
    defines += [ "APP_USE_ARM64" ]
  } else if (target_cpu == "arm") {
    defines += [ "APP_USE_ARM" ]
  } else if (target_cpu == "x86_64") {
    defines += [ "APP_USE_X86_64" ]
  }
  cflags = [
    "-fdata-sections",
    "-ffunction-sections",
    "-Os",
  ]

  cflags_cc = [ "-Os" ]
}

config("app_domain_verify_extension_public_config") {
  visibility = [ ":*" ]
  include_dirs = [
    "include",
    "${app_domain_verify_common_path}/include",
    "${app_domain_verify_common_path}/include/zidl",
  ]
}

ohos_shared_library("app_domain_verify_extension_framework") {
  branch_protector_ret = "pac_ret"
  sources = [
    "src/app_domain_verify_agent_ext.cpp",
    "src/app_domain_verify_extension_mgr.cpp",
    "src/app_domain_verify_extension_register.cpp",
  ]
  configs = [ ":app_domain_verify_extension_config" ]
  public_configs = [ ":app_domain_verify_extension_public_config" ]
  deps = [ "${app_domain_verify_common_path}:app_domain_verify_common" ]
  version_script = "extension.versionscript"
  external_deps = [
    "ability_base:want",
    "c_utils:utils",
    "hilog:libhilog",
    "hisysevent:libhisysevent",
    "ipc:ipc_single",
    "samgr:samgr_proxy",
  ]
  defines = []
  if (build_variant == "user") {
    defines += [ "IS_RELEASE_VERSION" ]
  }
  sanitize = {
    cfi = true
    cfi_cross_dso = true
    debug = false
  }
  subsystem_name = "bundlemanager"
  part_name = "app_domain_verify"
}