# Copyright (c) 2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/test.gni")
import("//foundation/graphic/graphic_2d/graphic_config.gni")

module_output_path = "graphic_2d/rosen/modules/2d_graphics/render_context"

group("unittest") {
  testonly = true

  deps = [
    ":2d_graphics_shader_cache_test",
    ":RenderContextTest",
  ]
}

## Build RenderContextTest
ohos_unittest("RenderContextTest") {
  module_out_path = module_output_path
  sources = [ "render_context_test.cpp" ]
  deps = [
    ":render_context",
    "$graphic_2d_root/rosen/modules/render_service_base:librender_service_base",
  ]
  if (defined(use_rosen_drawing) && use_rosen_drawing) {
    defines = [ "USE_ROSEN_DRAWING" ]
  }
  include_dirs =
      [ "$graphic_2d_root/rosen/modules/render_service_base/include" ]

  external_deps = [
    "c_utils:utils",
    "hilog:libhilog",
  ]
}

## Build render_context.a {{{
config("render_context_public_config") {
  include_dirs =
      [ "$graphic_2d_root/rosen/modules/2d_graphics/src/render_context" ]

  cflags = [
    "-Wall",
    "-Werror",
    "-g3",
    "-Dprivate=public",
    "-Dprotected=public",
  ]
}

ohos_static_library("render_context") {
  visibility = [ ":*" ]
  testonly = true

  public_configs = [ ":render_context_public_config" ]

  public_deps = [
    "$graphic_2d_root/rosen/modules/render_service_base:librender_service_base",
    "//third_party/googletest:gtest_main",
  ]
  subsystem_name = "graphic"
  part_name = "graphic_2d"
}

## Build render_context.a }}}

ohos_unittest("2d_graphics_shader_cache_test") {
  module_out_path = module_output_path

  sources = [
    "cache_data_test.cpp",
    "momory_handler_test.cpp",
    "shader_cache_test.cpp",
  ]

  include_dirs = [
    "$graphic_2d_root/rosen/modules/2d_engine",
    "$graphic_2d_root/rosen/modules/2d_graphics/src/render_context",
    "$graphic_2d_root/rosen/modules/2d_graphics/include",
    "$graphic_2d_root/rosen/modules/render_service_base/include",
  ]

  include_dirs += [ "//third_party/skia/" ]

  deps = [
    "$graphic_2d_root/rosen/modules/2d_graphics:2d_graphics",
    "$graphic_2d_root/rosen/modules/render_service_base:librender_service_base",
    "//third_party/googletest:gtest_main",
  ]

  external_deps = [ "hilog:libhilog" ]

  defines = []
  defines += gpu_defines

  part_name = "graphic_2d"
  subsystem_name = "graphic"
}