# Copyright (C) 2023 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/multimedia/av_codec/config.gni")

config("ffmpeg_adapter_config") {
  defines = [
    "HST_ANY_WITH_NO_RTTI",
    "MEDIA_OHOS",
  ]

  cflags = [
    "-fno-exceptions",
    "-Wall",
    "-fno-common",
    "-fstack-protector-all",
    "-Wshadow",
    "-FPIC",
    "-FS",
    "-O2",
    "-D_FORTIFY_SOURCE=2",
    "-Wformat=2",
    "-Wdate-time",
  ]

  cflags_cc = [
    "-std=c++17",
    "-fno-rtti",
  ]

  include_dirs = [
    "$av_codec_root_dir/interfaces",
    "$av_codec_root_dir/services/media_engine/plugins/ffmpeg_adapter",
    "$av_codec_root_dir/services/media_engine/plugins/ffmpeg_adapter/muxer",
    "$av_codec_root_dir/services/media_engine/plugins/ffmpeg_adapter/common",
  ]
}

ohos_shared_library("media_plugin_FFmpegMuxer") {
  branch_protector_ret = "pac_ret"
  install_enable = true

  sanitize = av_codec_sanitize

  configs = [
    ":ffmpeg_adapter_config",
    "$av_codec_root_dir/services/dfx:av_codec_service_log_dfx_public_config",
  ]

  sources = [
    "common/ffmpeg_converter.cpp",
    "common/ffmpeg_utils.cpp",
    "common/stream_parser_manager.cpp",
    "muxer/ffmpeg_muxer_plugin.cpp",
  ]

  public_external_deps = [ "ffmpeg:libohosffmpeg" ]

  external_deps = [
    "c_utils:utils",
    "hilog:libhilog",
    "media_foundation:media_foundation",
  ]

  relative_install_dir = "media/media_plugins"
  subsystem_name = "multimedia"
  part_name = "av_codec"
}

ohos_shared_library("media_plugin_FFmpegDemuxer") {
  branch_protector_ret = "pac_ret"
  install_enable = true

  sanitize = av_codec_sanitize

  defines = []

  defines += [
    "OHOS_EXPAND_MP4_INFO",
    "OHOS_AV3A_DEMUXER",
  ]

  if (build_variant != "user") {
    defines += [ "BUILD_ENG_VERSION" ]
  }

  configs = [
    ":ffmpeg_adapter_config",
    "$av_codec_root_dir/services/dfx:av_codec_service_log_dfx_public_config",
  ]

  sources = [
    "common/ffmpeg_converter.cpp",
    "common/ffmpeg_utils.cpp",
    "common/reference_parser_manager.cpp",
    "common/stream_parser_manager.cpp",
    "demuxer/block_queue_pool.cpp",
    "demuxer/demuxer_log_compressor.cpp",
    "demuxer/ffmpeg_demuxer_plugin.cpp",
    "demuxer/ffmpeg_format_helper.cpp",
    "demuxer/ffmpeg_reference_parser.cpp",
  ]

  deps = [ "$av_codec_root_dir/services/dfx:av_codec_service_dfx" ]

  public_external_deps = [ "ffmpeg:libohosffmpeg" ]

  external_deps = [
    "c_utils:utils",
    "hilog:libhilog",
    "init:libbegetutil",
    "media_foundation:media_foundation",
  ]

  relative_install_dir = "media/media_plugins"
  subsystem_name = "multimedia"
  part_name = "av_codec"
}