# Copyright (c) 2021 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//base/notification/common_event_service/event.gni")
import("//build/ohos.gni")

cflags = [
  "-fno-math-errno",
  "-fno-unroll-loops",
  "-fmerge-all-constants",
  "-fno-ident",
  "-Oz",
  "-flto",
  "-ffunction-sections",
  "-fdata-sections",
]

config("native_module_config") {
  visibility = [ ":*" ]

  include_dirs = []

  if (target_cpu == "arm") {
    cflags += [ "-DBINDER_IPC_32BIT" ]
  }
}

ohos_shared_library("commonevent") {
  sanitize = {
    integer_overflow = true
    ubsan = true
    boundary_sanitize = true
    cfi = true
    cfi_cross_dso = true
    debug = false
  }
  branch_protector_ret = "pac_ret"

  include_dirs = [
    "${interfaces_path}/kits/napi/common_event/include",
    "//third_party/node/src",
    "//third_party/libuv/include",
    "${interfaces_path}/kits/napi/support/include",
  ]

  configs = [ ":native_module_config" ]

  sources = [
    "${interfaces_path}/kits/napi/support/src/support.cpp",
    "src/common_event.cpp",
    "src/common_event_parse.cpp",
    "src/common_event_set_param.cpp",
    "src/init.cpp",
  ]

  deps = [ "${ces_native_path}:cesfwk_innerkits" ]

  external_deps = [
    "ability_base:want",
    "ability_runtime:abilitykit_native",
    "ability_runtime:napi_common",
    "c_utils:utils",
    "hilog:libhilog",
    "napi:ace_napi",
  ]

  relative_install_dir = "module"
  subsystem_name = "notification"
  part_name = "common_event_service"
}