# Copyright (c) 2023 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//base/security/device_auth/deps_adapter/deviceauth_hals.gni")
import("//base/security/device_auth/services/deviceauth.gni")

#####################hydra-fuzz###################
import("//build/config/features.gni")
import("//build/ohos.gni")
import("//build/test.gni")
module_output_path = "device_auth/device_auth"

##############################fuzztest##########################################
ohos_fuzztest("DevAuthFuzzTest") {
  module_out_path = module_output_path
  fuzz_config_file = "${deviceauth_path}/test/fuzztest/devauth_fuzzer"
  include_dirs = inc_path + hals_inc_path
  include_dirs += [
    ".",
    "${frameworks_path}/inc/standard",
    "${dev_frameworks_path}/inc/hiview_adapter",
    "${dev_frameworks_path}/inc/permission_adapter",
  ]
  if (support_os_account) {
    include_dirs += [ "${dev_frameworks_path}/inc/account_subscriber" ]
    include_dirs += [ "${dev_frameworks_path}/inc/sa_subscriber" ]
  }
  include_dirs += identity_manager_inc

  sources = [ "devauth_fuzzer.cpp" ]
  sources += deviceauth_ipc_files
  sources += permission_adapter_files
  sources += [ "${frameworks_path}/src/ipc_service.c" ]
  sources += deviceauth_files
  if (support_os_account) {
    sources += account_subscriber_files
    sources += sa_subscriber_files
  }
  sources += hiview_adapter_files
  sources += identity_manager_files
  defines = [ "HILOG_ENABLE" ]
  defines += [ "DEV_AUTH_HIVIEW_ENABLE" ]
  defines += [ "DEV_AUTH_FUZZ_TEST" ]
  cflags = [
    "-g",
    "-O0",
    "-Wno-unused-variable",
    "-fno-omit-frame-pointer",
    "-DHILOG_ENABLE",
  ]
  cflags += build_flags
  cflags += [
    "-DDEV_AUTH_WORK_THREAD_STACK_SIZE=${device_auth_hichain_thread_stack_size}",
    "-DMAX_AUTH_SESSION_COUNT=${max_auth_session_count}",
  ]
  sanitize = {
    cfi = true
    cfi_cross_dso = true
    integer_overflow = true
    boundary_sanitize = true
    ubsan = true
    debug = true
  }
  if (target_cpu == "arm") {
    cflags += [ "-DBINDER_IPC_32BIT" ]
  }
  deps = [ "${deps_adapter_path}:${hal_module_test_name}" ]
  external_deps = [
    "access_token:libaccesstoken_sdk",
    "access_token:libnativetoken",
    "access_token:libtoken_setproc",
    "cJSON:cjson",
    "c_utils:utils",
    "dsoftbus:softbus_client",
    "hilog:libhilog",
    "hisysevent:libhisysevent",
    "hitrace:hitrace_meter",
    "init:libbegetutil",
    "ipc:ipc_core",
    "samgr:samgr_proxy",
  ]
  if (support_os_account) {
    external_deps += [
      "ability_base:want",
      "common_event_service:cesfwk_innerkits",
      "ipc:ipc_single",
      "os_account:os_account_innerkits",
      "samgr:samgr_proxy",
    ]
  }
}

###############################################################################
group("fuzztest") {
  testonly = true
  deps = []
  deps += [
    # deps file
    ":DevAuthFuzzTest",
  ]
}
###############################################################################