# Copyright (c) 2022-2023 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("../../../../hdf_core/adapter/uhdf2/uhdf.gni")
import("../../wlan.gni")

HDI_SERVICE_ROOT_DIR = "../.."

ohos_shared_library("libwlan_service_extend") {
  branch_protector_ret = "pac_ret"
  sanitize = {
    cfi = true  # Enable/disable control flow integrity detection
    boundary_sanitize = true  # Enable boundary san detection
    cfi_cross_dso = true  # Cross-SO CFI Checks
    integer_overflow = true  # Enable integer overflow detection
    ubsan = true  # Enable some Ubsan options
    debug = false
  }
  include_dirs = [
    "$HDI_SERVICE_ROOT_DIR/interfaces/include",
    "$HDI_SERVICE_ROOT_DIR/client/include",
    "$HDI_SERVICE_ROOT_DIR/hal/include",
    "$HDI_SERVICE_ROOT_DIR/hdi_service/service_common",
    "$HDI_SERVICE_ROOT_DIR/hdi_service/service_extend",
  ]
  sources = []

  if (drivers_peripheral_wlan_feature_enable_HDF_WLAN_EXTEND_VDI) {
    sources += [ "service_extend_vdi/wlan_extend_cmd.c" ]
  } else {
    sources += [ "service_extend_direct/wlan_extend_cmd.c" ]
  }

  deps = [ "$HDI_SERVICE_ROOT_DIR/hal:wifi_hal" ]

  external_deps = [ "drivers_interface_wlan:wlan_idl_headers" ]

  defines = [ "__OHOS__USER__" ]

  cflags = [
    "-Wall",
    "-Wextra",
    "-Werror",
    "-fsigned-char",
    "-fno-common",
    "-fno-strict-aliasing",
    "-fstack-protector-all",
  ]

  if (is_standard_system) {
    external_deps += [
      "c_utils:utils",
      "hdf_core:libhdf_host",
      "hdf_core:libhdf_ipc_adapter",
      "hdf_core:libhdf_utils",
      "hilog:libhilog",
    ]
  } else {
    external_deps += [ "hilog:libhilog" ]
  }

  install_images = [ chipset_base_dir ]
  subsystem_name = "hdf"
  part_name = "drivers_peripheral_wlan"
}