# Copyright (c) 2020 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
import("//build/lite/config/component/lite_component.gni")
import("//foundation/ability/ability_lite/ability_lite.gni")

generate_notice_file("want_notice_file") {
  module_name = "want"
  module_source_dir_list = [ "//third_party/bounds_checking_function" ]
}

static_library("want") {
  sources = [ "src/want.cpp" ]
  cflags = []
  if (board_toolchain_type != "iccarm") {
    cflags += [
      "-fPIC",
      "-Wall",
    ]
  }
  cflags_cc = cflags

  include_dirs = [
    "include",
    "${utils_lite_path}/include",
    "${utils_lite_path}/memory/include",
    "${communication_path}/ipc/interfaces/innerkits/c/ipc/include",
    "//third_party/bounds_checking_function/include",
    "${aafwk_lite_path}/interfaces/kits/want_lite",
    "${appexecfwk_lite_path}/interfaces/kits/bundle_lite",
    "${appexecfwk_lite_path}/frameworks/bundle_lite/include",
    "${appexecfwk_lite_path}/utils/bundle_lite",
  ]

  if (ohos_kernel_type == "liteos_m") {
    deps = [ "${hilog_lite_path}/frameworks/featured:hilog_static" ]
    include_dirs += [ "${hilog_lite_path}/interfaces/native/kits/hilog_lite" ]
  } else {
    defines = [ "OHOS_APPEXECFWK_BMS_BUNDLEMANAGER" ]
    deps = [ "${hilog_lite_path}/frameworks/featured:hilog_shared" ]
  }
}