# Copyright (C) 2023 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/bundlemanager/app_domain_verify/app_domain_verify.gni")

config("app_domain_verify_service_config") {
  visibility = [ ":*" ]
  include_dirs = [
    "${app_domain_verify_client_path}/include",
    "include/manager/constant",
    "include/manager/core",
    "include/manager/rdb",
    "include/manager/zidl",
    "include/manager/permission",
    "include/agent/core",
    "${app_domain_verify_common_path}/include",
    "${app_domain_verify_common_path}/include/zidl",
    "${app_domain_verify_frameworks_common_path}/include",
    "${app_domain_verify_frameworks_common_path}/include/utils",
    "${app_domain_verify_frameworks_common_path}/include/config",
  ]
  configs = [ "//build/config/compiler:exceptions" ]
  ldflags = [ "-Wl,--exclude-libs=ALL" ]
  cflags = [
    "-fvisibility=hidden",
    "-fdata-sections",
    "-ffunction-sections",
    "-Os",
  ]

  cflags_cc = [
    "-fvisibility-inlines-hidden",
    "-Os",
  ]
}

ohos_shared_library("app_domain_verify_mgr_service") {
  branch_protector_ret = "pac_ret"
  sources = [
    "${app_domain_verify_frameworks_common_path}/src/config/white_list_config_mgr.cpp",
    "${app_domain_verify_frameworks_common_path}/src/utils/domain_url_util.cpp",
    "src/manager/core/app_domain_verify_data_mgr.cpp",
    "src/manager/core/app_domain_verify_mgr_service.cpp",
    "src/manager/permission/permission_manager.cpp",
    "src/manager/rdb/app_domain_verify_rdb_data_manager.cpp",
    "src/manager/rdb/app_domain_verify_rdb_open_callback.cpp",
    "src/manager/rdb/rdb_migrate_mgr.cpp",
    "src/manager/zidl/app_domain_verify_mgr_service_proxy.cpp",
    "src/manager/zidl/app_domain_verify_mgr_service_stub.cpp",
  ]
  public_configs = [ ":app_domain_verify_service_config" ]
  deps = [
    "${app_domain_verify_client_path}:app_domain_verify_agent_client",
    "${app_domain_verify_common_path}:app_domain_verify_common",
  ]
  defines = [ "API_EXPORT=__attribute__((visibility (\"default\")))" ]
  if (build_variant == "user") {
    defines += [ "IS_RELEASE_VERSION" ]
  }
  external_deps = [
    "ability_base:base",
    "ability_base:want",
    "ability_base:zuri",
    "ability_runtime:ability_manager",
    "access_token:libaccesstoken_sdk",
    "access_token:libtokenid_sdk",
    "bundle_framework:appexecfwk_base",
    "bundle_framework:appexecfwk_core",
    "c_utils:utils",
    "eventhandler:libeventhandler",
    "ffrt:libffrt",
    "hilog:libhilog",
    "hisysevent:libhisysevent",
    "ipc:ipc_core",
    "json:nlohmann_json_static",
    "preferences:native_preferences",
    "relational_store:native_rdb",
    "safwk:system_ability_fwk",
    "samgr:samgr_proxy",
  ]

  sanitize = {
    cfi = true
    cfi_cross_dso = true
    debug = false
  }
  subsystem_name = "bundlemanager"
  part_name = "app_domain_verify"
}

config("app_domain_verify_agent_service_config") {
  visibility = [ ":*" ]
  include_dirs = [
    "${app_domain_verify_client_path}/include",
    "include/agent/data_share",
    "include/agent/core",
    "include/agent/zidl",
    "include/manager/core",
    "include/manager/zidl",
    "include/manager/rdb",
    "${app_domain_verify_common_path}/include",
    "${app_domain_verify_common_path}/include/zidl",
    "${app_domain_verify_frameworks_common_path}/include",
    "${app_domain_verify_frameworks_common_path}/include/utils",
    "${app_domain_verify_frameworks_common_path}/include/bms",
    "${app_domain_verify_frameworks_common_path}/include/config",
    "${app_domain_verify_frameworks_extension_path}/include",
    "${app_domain_verify_frameworks_verifier_path}/include",
  ]
  configs = [ "//build/config/compiler:exceptions" ]
  ldflags = [ "-Wl,--exclude-libs=ALL" ]
  cflags = [
    "-fvisibility=hidden",
    "-fdata-sections",
    "-ffunction-sections",
    "-Os",
  ]

  cflags_cc = [
    "-fvisibility-inlines-hidden",
    "-Os",
  ]
}

ohos_shared_library("app_domain_verify_agent_service") {
  branch_protector_ret = "pac_ret"
  sources = [
    "src/agent/core/app_domain_verify_agent_service.cpp",
    "src/agent/data_share/setting_data_share_helper.cpp",
    "src/agent/zidl/app_domain_verify_agent_service_proxy.cpp",
    "src/agent/zidl/app_domain_verify_agent_service_stub.cpp",
  ]
  public_configs = [ ":app_domain_verify_agent_service_config" ]
  defines = [ "API_EXPORT=__attribute__((visibility (\"default\")))" ]
  if (build_variant == "user") {
    defines += [ "IS_RELEASE_VERSION" ]
  }
  deps = [
    "${app_domain_verify_client_path}:app_domain_verify_mgr_client",
    "${app_domain_verify_common_path}:app_domain_verify_common",
    "${app_domain_verify_frameworks_common_path}:app_domain_verify_frameworks_common",
    "${app_domain_verify_frameworks_extension_path}:app_domain_verify_extension_framework",
    "${app_domain_verify_frameworks_verifier_path}:app_domain_verify_agent_verifier",
  ]

  external_deps = [
    "ability_base:base",
    "ability_base:want",
    "ability_base:zuri",
    "ability_runtime:ability_manager",
    "bundle_framework:appexecfwk_core",
    "c_utils:utils",
    "curl:curl_shared",
    "data_share:datashare_consumer",
    "eventhandler:libeventhandler",
    "ffrt:libffrt",
    "hicollie:libhicollie",
    "hilog:libhilog",
    "hisysevent:libhisysevent",
    "ipc:ipc_core",
    "json:nlohmann_json_static",
    "netmanager_base:net_conn_manager_if",
    "netstack:http_client",
    "os_account:os_account_innerkits",
    "preferences:native_preferences",
    "safwk:system_ability_fwk",
    "samgr:samgr_proxy",
  ]

  sanitize = {
    cfi = true
    cfi_cross_dso = true
    debug = false
  }
  subsystem_name = "bundlemanager"
  part_name = "app_domain_verify"
}