# Copyright (C) 2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//build/ohos_var.gni")
import("../../../nfc.gni")

config("nfc_inner_kits_config") {
  visibility = [ ":*" ]
  defines = [ "DEBUG" ]
  cflags_cc = [ "-fexceptions" ]

  include_dirs = []
}

config("nfc_inner_kits_public_config") {
  visibility = [ ":*" ]
  defines = []
  if (nfc_service_feature_vendor_applications_enabled) {
    defines += [ "VENDOR_APPLICATIONS_ENABLED" ]
  }
  include_dirs = [
    "$NFC_DIR/interfaces/inner_api/common",
    "$NFC_DIR/interfaces/inner_api/controller",
  ]
}

ohos_shared_library("nfc_inner_kits_controller") {
  sanitize = {
    cfi = true
    boundary_sanitize = true
    integer_overflow = true
    cfi_cross_dso = true
    debug = false
    ubsan = true
  }
  branch_protector_ret = "pac_ret"
  sources = [
    "ndef_msg_callback_stub.cpp",
    "nfc_controller.cpp",
    "nfc_controller_callback_stub.cpp",
    "nfc_controller_proxy.cpp",
    "nfc_data_share_impl.cpp",
    "nfc_sa_client.cpp",
  ]
  if (nfc_service_feature_vendor_applications_enabled) {
    sources += [
      "on_card_emulation_notify_cb_stub.cpp",
      "query_app_info_callback_stub.cpp",
    ]
  }
  configs = [ ":nfc_inner_kits_config" ]

  public_configs = [ ":nfc_inner_kits_public_config" ]

  deps = [ "../common:nfc_inner_kits_common" ]

  external_deps = [
    "ability_base:want",
    "ability_base:zuri",
    "ability_runtime:dataobs_manager",
    "bundle_framework:appexecfwk_base",
    "c_utils:utils",
    "data_share:datashare_common",
    "data_share:datashare_consumer",
    "hilog:libhilog",
    "ipc:ipc_core",
    "samgr:samgr_proxy",
  ]

  part_name = "nfc"
  subsystem_name = "communication"
}