# Copyright (c) 2022 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
import("//build/ohos.gni")
import("//build/ohos/ace/ace.gni")
import("//foundation/distributeddatamgr/relational_store/relational_store.gni")

ohos_copy("relational_store_declaration") {
  sources = [ "./api" ]
  outputs = [ target_out_dir + "/$target_name/" ]
  module_source_dir = target_out_dir + "/$target_name"
  module_install_name = ""
}

ohos_shared_library("napi_rdb") {
  sources = [
    "../common/src/js_utils.cpp",
    "src/napi_async_call.cpp",
    "src/napi_rdb_const_properties.cpp",
    "src/napi_rdb_js_utils.cpp",
    "src/napi_rdb_predicates.cpp",
    "src/napi_rdb_store.cpp",
    "src/napi_rdb_store_helper.cpp",
    "src/napi_result_set.cpp",
    "src/napi_uv_queue.cpp",
    "src/napi_values_bucket.cpp",
  ]

  if (is_mingw || is_mac) {
    include_dirs = [
      "mock/include",
      "${kvstore_path}/common",
      "${relational_store_common_path}/include",
      "${relational_store_js_common_path}/mock/include",
      "${relational_store_napi_path}/rdb/mock/include",
      "//commonlibrary/c_utils/base/include",
      "include",
      "${relational_store_js_common_path}/include",
    ]
    cflags_cc = [
      "-std=c++17",
      "-stdlib=libc++",
    ]
    if (is_mac) {
      buildos = "mac"
      defines = [ "MAC_PLATFORM" ]
    } else {
      buildos = "windows"
      defines = [ "WINDOWS_PLATFORM" ]
    }
    sources += [ "${relational_store_js_common_path}/mock/src/js_ability.cpp" ]
    deps = [
      "//base/hiviewdfx/hilog/interfaces/native/innerkits:libhilog_${buildos}",
      "//foundation/arkui/napi:ace_napi",
      "//foundation/distributeddatamgr/relational_store/interfaces/inner_api/rdb:native_rdb",
    ]

    external_deps = [ "bounds_checking_function:libsec_static" ]
  } else {
    include_dirs = [
      "include",
      "${datashare_path}/common/include/",
      "${kvstore_path}/common",
      "${relational_store_common_path}/include",
      "${relational_store_js_common_path}/include",
      "${relational_store_napi_path}/rdb/include",
    ]
    defines = [ "SQLITE_DISTRIBUTE_RELATIONAL" ]
    sources += [
      "${relational_store_js_common_path}/src/js_ability.cpp",
      "src/napi_rdb_store_observer.cpp",
    ]

    deps = [
      "${relational_store_innerapi_path}/appdatafwk:native_appdatafwk",
      "${relational_store_innerapi_path}/rdb:native_rdb",
      "${relational_store_innerapi_path}/rdb_data_share_adapter:rdb_data_share_adapter",
    ]

    external_deps = [
      "ability_runtime:abilitykit_native",
      "ability_runtime:napi_base_context",
      "bounds_checking_function:libsec_shared",
      "c_utils:utils",
      "common_event_service:cesfwk_innerkits",
      "hilog:libhilog",
      "hitrace:hitrace_meter",
      "napi:ace_napi",
    ]
  }

  subsystem_name = "distributeddatamgr"
  innerapi_tags = [ "platformsdk" ]
  part_name = "relational_store"
}

ohos_shared_library("rdb") {
  sources = [ "src/entry_point.cpp" ]

  if (is_mingw || is_mac) {
    include_dirs = [
      "mock/include",
      "${relational_store_common_path}/include",
      "${relational_store_js_common_path}/mock/include",
      "${relational_store_napi_path}/rdb/mock/include",
      "//commonlibrary/c_utils/base/include",
      "include",
      "${relational_store_js_common_path}/include",
    ]
    cflags_cc = [
      "-std=c++17",
      "-stdlib=libc++",
    ]
    if (is_mac) {
      buildos = "mac"
      defines = [ "MAC_PLATFORM" ]
    } else {
      buildos = "windows"
      defines = [ "WINDOWS_PLATFORM" ]
    }

    deps = [
      ":napi_rdb",
      "//base/hiviewdfx/hilog/interfaces/native/innerkits:libhilog_${buildos}",
      "//foundation/arkui/napi:ace_napi",
      "//foundation/distributeddatamgr/relational_store/interfaces/inner_api/rdb:native_rdb",
    ]
  } else {
    include_dirs = [
      "include",
      "${datashare_path}/common/include/",
      "${relational_store_js_common_path}/include",
      "${relational_store_napi_path}/rdb/include",
    ]
    defines = [ "SQLITE_DISTRIBUTE_RELATIONAL" ]

    deps = [
      ":napi_rdb",
      "${relational_store_innerapi_path}/appdatafwk:native_appdatafwk",
      "${relational_store_innerapi_path}/rdb:native_rdb",
      "${relational_store_innerapi_path}/rdb_data_share_adapter:rdb_data_share_adapter",
    ]

    external_deps = [
      "ability_runtime:abilitykit_native",
      "ability_runtime:napi_base_context",
      "c_utils:utils",
      "hilog:libhilog",
      "hitrace:hitrace_meter",
      "napi:ace_napi",
    ]
  }

  subsystem_name = "distributeddatamgr"
  part_name = "relational_store"
  relative_install_dir = "module/data"
}