# Copyright (C) 2024 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("//foundation/filemanagement/app_file_service/app_file_service.gni")
import("//foundation/filemanagement/app_file_service/backup.gni")

ohos_shared_library("cj_file_fileuri_ffi") {
  sanitize = {
    integer_overflow = true
    ubsan = true
    boundary_sanitize = true
    cfi = true
    cfi_cross_dso = true
    debug = false
  }

  include_dirs = [
    "${app_file_service_path}/interfaces/innerkits/native/file_uri/include",
    "src",
  ]

  if (!defined(defines)) {
    defines = []
  }

  use_exceptions = true

  if (product_name != "ohos-sdk") {
    deps = [
      "${app_file_service_path}/interfaces/innerkits/native:fileuri_native",
      "${path_backup}/utils:backup_utils",
    ]
    external_deps = [
      "ability_base:zuri",
      "ability_runtime:abilitykit_native",
      "bundle_framework:appexecfwk_base",
      "bundle_framework:appexecfwk_core",
      "c_utils:utils",
      "file_api:filemgmt_libhilog",
      "file_api:filemgmt_libn",
      "hilog:libhilog",
      "ipc:ipc_core",
      "napi:cj_bind_ffi",
      "napi:cj_bind_native",
      "samgr:samgr_proxy",
    ]
    sources = [
      "src/file_fileuri_ffi.cpp",
      "src/file_uri.cpp",
    ]
  } else {
    defines += [ "PREVIEWER" ]
    sources = [ "src/fileuri_mock.cpp" ]
  }

  if (current_os == "ohos") {
    defines += [ "OHOS_PLATFORM" ]
  }

  if (current_os == "mingw") {
    defines += [ "WINDOWS_PLATFORM" ]
  }

  innerapi_tags = [ "platformsdk" ]
  part_name = "app_file_service"
  subsystem_name = "filemanagement"
}