# Copyright (c) 2022-2023 Huawei Device Co., Ltd.
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("//build/ohos.gni")
import("../../../castplus_cast_engine_part.gni")
import("../../../config.gni")

config("avsession_client_config") {
  include_dirs = [
    "include",
    "../../../interfaces/inner_api/native/session/include",
    "../../../services/session/ipc/base",
    "../../../services/session/ipc/proxy",
    "../../../services/session/ipc/stub",
  ]
}

ohos_shared_library("avsession_client") {
  install_enable = true
  ipc_sources = [
    "../../../services/session/ipc/proxy/avsession_controller_proxy.cpp",
    "../../../services/session/ipc/proxy/avsession_proxy.cpp",
    "../../../services/session/ipc/proxy/avsession_service_proxy.cpp",
    "../../../services/session/ipc/stub/avcontroller_callback_stub.cpp",
    "../../../services/session/ipc/stub/avsession_callback_stub.cpp",
    "../../../services/session/ipc/stub/session_listener_stub.cpp",
  ]

  client_sources = [
    "src/avcontroller_callback_client.cpp",
    "src/avsession_callback_client.cpp",
    "src/avsession_manager.cpp",
    "src/avsession_manager_impl.cpp",
    "src/avsession_pixel_map_adapter.cpp",
    "src/session_listener_client.cpp",
  ]

  sanitize = {
    cfi = true
    cfi_cross_dso = true
    debug = false
  }

  sources = ipc_sources + client_sources

  public_configs = [ ":avsession_client_config" ]

  public_deps = [
    "../../../utils:avsession_utils",
    "../../common:avsession_common",
  ]

  external_deps = [
    "ability_base:want",
    "ability_runtime:wantagent_innerkits",
    "audio_framework:audio_client",
    "c_utils:utils",
    "hilog:libhilog",
    "image_framework:image_native",
    "input:libmmi-client",
    "ipc:ipc_single",
    "samgr:samgr_proxy",
  ]

  cflags = []

  if (castplus_cast_engine_enable) {
    cflags += [ "-DCASTPLUS_CAST_ENGINE_ENABLE" ]
    public_deps += [ "./../session:avsession_cast_client" ]
  }

  if (multimedia_av_session_enable_trace_control) {
    cflags += [ "-DENBABLE_AVSESSION_TRACE_CONTROL" ]
    external_deps += [ "hitrace:hitrace_meter" ]
  }
  if (multimedia_av_session_enable_sysevent_control) {
    cflags += [ "-DENABLE_AVSESSION_SYSEVENT_CONTROL" ]
    external_deps += [ "hisysevent:libhisysevent" ]
  }

  innerapi_tags = [ "platformsdk" ]
  subsystem_name = "multimedia"
  part_name = "av_session"
}

ohos_shared_library("avsession_cast_client") {
  install_enable = true
  sanitize = {
    cfi = true
    cfi_cross_dso = true
    debug = false
  }
  ipc_sources = [
    "../../../services/session/ipc/proxy/avcast_controller_proxy.cpp",
    "../../../services/session/ipc/stub/avcast_controller_callback_stub.cpp",
  ]

  client_sources = [ "src/avcast_controller_callback_client.cpp" ]

  sources = ipc_sources + client_sources

  public_configs = [ ":avsession_client_config" ]

  public_deps = [
    "../../../utils:avsession_utils",
    "../../common:avsession_common",
  ]

  external_deps = [
    "ability_base:want",
    "ability_runtime:wantagent_innerkits",
    "audio_framework:audio_client",
    "c_utils:utils",
    "graphic_surface:surface",
    "hilog:libhilog",
    "image_framework:image_native",
    "input:libmmi-client",
    "ipc:ipc_single",
    "samgr:samgr_proxy",
  ]

  cflags = []

  if (multimedia_av_session_enable_trace_control) {
    cflags += [ "-DENBABLE_AVSESSION_TRACE_CONTROL" ]
    external_deps += [ "hitrace:hitrace_meter" ]
  }

  if (multimedia_av_session_enable_sysevent_control) {
    cflags += [ "-DENABLE_AVSESSION_SYSEVENT_CONTROL" ]
    external_deps += [ "hisysevent:libhisysevent" ]
  }

  innerapi_tags = [ "platformsdk" ]
  subsystem_name = "multimedia"
  part_name = "av_session"
}