1# Copyright (c) 2022 Huawei Device Co., Ltd.
2# Licensed under the Apache License, Version 2.0 (the "License");
3# you may not use this file except in compliance with the License.
4# You may obtain a copy of the License at
5#
6#     http://www.apache.org/licenses/LICENSE-2.0
7#
8# Unless required by applicable law or agreed to in writing, software
9# distributed under the License is distributed on an "AS IS" BASIS,
10# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11# See the License for the specific language governing permissions and
12# limitations under the License.
13
14import("//build/ohos.gni")
15import("//foundation/arkui/ace_engine/ace_config.gni")
16
17template("napi_animator_static") {
18  forward_variables_from(invoker, "*")
19
20  ohos_source_set(target_name) {
21    defines += invoker.defines
22    cflags_cc += invoker.cflags_cc
23    configs = [ "$ace_root/interfaces/napi/kits:ace_napi_config" ]
24
25    sources = [ "js_animator.cpp" ]
26    deps = []
27    external_deps = []
28    if (platform != "" && is_arkui_x) {
29      deps += [ "//plugins/libs/napi:napi_$platform" ]
30    } else {
31      external_deps += [ "napi:ace_napi" ]
32    }
33
34    if (use_hilog) {
35      external_deps += [ "hilog:libhilog" ]
36    }
37
38    if (defined(config.libace_target)) {
39      deps += [ config.libace_target ]
40    }
41
42    deps += [ "../utils:napi_utils_static_${platform}" ]
43
44    subsystem_name = ace_engine_subsystem
45    part_name = ace_engine_part
46  }
47}
48
49foreach(item, ace_platforms) {
50  napi_animator_static("animator_static_" + item.name) {
51    defines = []
52    cflags_cc = []
53    config = {
54    }
55    platform = item.name
56
57    if (defined(item.config)) {
58      config = item.config
59    }
60
61    if (defined(config.defines)) {
62      defines = config.defines
63    }
64
65    if (defined(config.cflags_cc)) {
66      cflags_cc = config.cflags_cc
67    }
68  }
69}
70