1# Copyright (c) 2021 Huawei Device Co., Ltd.
2# Licensed under the Apache License, Version 2.0 (the "License");
3# you may not use this file except in compliance with the License.
4# You may obtain a copy of the License at
5#
6#     http://www.apache.org/licenses/LICENSE-2.0
7#
8# Unless required by applicable law or agreed to in writing, software
9# distributed under the License is distributed on an "AS IS" BASIS,
10# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11# See the License for the specific language governing permissions and
12# limitations under the License.
13
14import("//build/ohos.gni")
15import("//foundation/arkui/ace_engine/ace_config.gni")
16
17# build core sources
18template("ace_core_pipeline_source_set") {
19  forward_variables_from(invoker, "*")
20
21  ohos_source_set(target_name) {
22    subsystem_name = ace_engine_subsystem
23    part_name = ace_engine_part
24    if (current_os == "ohos") {
25      sanitize = {
26        integer_overflow = true
27        boundary_sanitize = true
28        debug = ace_sanitize_debug
29      }
30    }
31    defines += invoker.defines
32
33    # add common source file needed by all product platform here
34    sources = [
35      # context
36      "pipeline_base.cpp",
37      "pipeline_context.cpp",
38
39      # base component
40      "base/component.cpp",
41      "base/component_group_element.cpp",
42      "base/composed_component.cpp",
43      "base/composed_element.cpp",
44      "base/constants.cpp",
45      "base/element.cpp",
46      "base/element_register.cpp",
47      "base/multi_composed_component.cpp",
48      "base/multi_composed_element.cpp",
49      "base/related_node.cpp",
50      "base/render_context_creator.cpp",
51      "base/render_element.cpp",
52      "base/render_node.cpp",
53      "base/sole_child_element.cpp",
54
55      # factories
56      "base/factories/render_node_factory.cpp",
57    ]
58
59    configs = [ "$ace_root:ace_config" ]
60
61    deps = [ "$ace_root/frameworks/core/components/theme:build_theme_code" ]
62    external_deps = []
63    if (use_hilog) {
64      external_deps += [ "hilog:libhilog" ]
65    }
66    if (defined(config.enable_rosen_backend) && config.enable_rosen_backend) {
67      sources += [ "base/rosen_render_context.cpp" ]
68      if (is_arkui_x) {
69        deps += [ "//foundation/graphic/graphic_2d/rosen/modules/render_service_client:librender_service_client_static" ]
70      } else {
71        external_deps += [ "graphic_2d:librender_service_client" ]
72        if (ace_use_rosen_drawing) {
73          external_deps += [ "graphic_2d:2d_graphics" ]
74        }
75      }
76    }
77
78    cflags_cc = []
79    cflags_cc += invoker.cflags_cc
80  }
81}
82
83foreach(item, ace_platforms) {
84  ace_core_pipeline_source_set("ace_core_pipeline_" + item.name) {
85    if (defined(item.config)) {
86      config = item.config
87    } else {
88      config = {
89      }
90    }
91
92    if (defined(config.defines)) {
93      defines = config.defines
94    } else {
95      defines = []
96    }
97
98    if (defined(config.cflags_cc)) {
99      cflags_cc = config.cflags_cc
100    } else {
101      cflags_cc = []
102    }
103  }
104}
105